## DSolve(equation, dependent(independent), values, mode=1)

equation
The differential equation to be solved. If no equal sign is found in the equation then DSolve assumes that the equation is equal to zero.

dependent(independent)
The dependent variable as a function of the independent variable. This should be in the form of f(t), g(t), y(t), y(x), x(t) and so forth.

values
The given initial values. For no initial values input the variable no.

mode=1
mode=1 forces a solution to be solved for the dependent variable or returns the answer as an implicit equation if the answer cannot be solved for the dependent variable.
mode=0 solves implicitly.

## Description

DSolve is a differential equation solver.

The derivative of the variable is notated using derivative notation. MathStudio uses the single quotation character to represent the derivative of a variable or function.

f'(x) - First derivative
f''(x) - Second derivative
f'''(x) - Third derivative

Derivative Examples
Solve: y' + y = sin(t)
DSolve(y'(t)+y(t)=sin(t), y(t), .....)

Solve: y'' + 2y' + y = x
DSolve(y''(x)+2y'(x)+y(x)=x, y(x), .....)

The definite integral of the variable is represented by I(f(t), t) and denotes the integral of the variable f(t) with lower bound 0 and upper bound t. These bounds cannot be changed.

Integral Examples
∫(y) + y = sin(t)
DSolve( I(y(t),t) + y(t) = sin(t), y(t), .....)

The upper case character I indicates the integral and is a mandatory condition.

Initial values
When no initial values are given, then simple write the word no. The result returned contains the Constant C@_1.

For first order differential equations the initial value can be given as y(t)=value. When you ommit y(t), then y(0) is assumed.

For higher order differential equations, the initial values should be given as a list and are always referred to zero : [y(0), y'(0), y''(0), ...]

Examples with different initial values
Solve: y' + y = sin(t) with y(0) = 5
DSolve(y'(t) + y(t) = sin(t) , y(t) , y(0) = 5)
or
DSolve(y(t)' + y(t) = sin(t) , y(t) , 5)

Solve: y' + y = sin(t) with y(2) = 5
DSolve(y(t)' + y(t) = sin(t) , y(t) , y(2)=5)

Solve: y'' + 2y' + y = x with y(0) = 1 and y'(0) = 2
DSolve(y''(x) + 2y'(x) + y(x) = x, y(x), [1,2])

Solve: y'' + 2y' + y = x with no initial values
DSolve(y''(x) + 2y'(x) + y(x) = x, y(x), no)

Different form for exact first order differential equations.
Exact first order differential equation can be given with d@_x , d@_t , d@_y, ect.

First Order Examples
Solve: dy = sin(t) * dt
DSolve(d@_y = sin(t) * d@_t, y(t), .....)

Of course, this can also be written as the following equation.
DSolve(y'(t) = sin(t) , y(t), ...)
Note: The variable to be solved should still be written as y(t).

Results
Normally, DSolve tries to return the result as y(t) = function(t).

In case y(t) cannot be represented in a simple form then the result is returned in implicit form.
function(y , t) = 0

In the latter case, the text Implicit result is added to call the users attention that the result is not of the form y(t)=function(t).

## Examples

DSolve(y'(t)+y(t)=sin(t), y(t), no)
DSolve(y''(x)+2y'(x)+y(x)=x, y(x), no)
DSolve(y''(x)+2y'(x)+y(x)=x, y(x), [1, 5])
DSolve(R*q'(t)+q(t)/C=U*sin(t), q(t), no)
DSolve(4*q'(t)+2q(t)=U*sin(t), q(t), y(0)=0)
DSolve(d@_y=sin(t)*d@_t, y(t), no)
DSolve(d@_y=sin(t)*d@_t, y(t), y(0)=1)
DSolve(x'(t)=-2*x(t)^2, x(t), no)
DSolve(x'(t)=-2*x(t)^2, x(t), y(1)=2)
DSolve(y'(t)=3t^2*exp(-y(t)), y(t), y(0)=1)
DSolve(x^2*y'(x)+3*x*y(x)=x^3, y(x), y(1)=A)
DSolve(x'(t)=6*sin(t)/x(t), x(t), no)
DSolve(x'(t)=6*sin(t)/x(t), x(t), y(@pi/4)=2)
DSolve(x'(t)=6*sin(t)/x(t), x(t), y(@pi/4)=2, 0)
DSolve(f(z)^2+2*z*f(z)*f'(z), f(z), no, 0)
DSolve(f(z)^2+2*z*f(z)*f'(z), f(z), no)
DSolve(f(z)^2+2*z*f(z)*f'(z), f(z), f(1)=5)
DSolve((a+b*x)*d@_x+(e+x+c)*d@_y, y(x), no)
DSolve((a+b*x)*d@_x+(e+x+c)*d@_y, y(x), a)
DSolve((a+b*x)+(e+x+c)*y'(x), y(x), no)
DSolve((a+b*x)+(e+x+c)*y'(x), y(x), a)
DSolve(x*f'(x)+x+f(x), f(x), f(1)=a, 0)
DSolve(y'(t)+2a*y(t)=t^2, y(t), y(1)=0)

## References

http://en.wikipedia.org/wiki/Ordinary_differential_equation

## Related Functions

Diff, Integrate, Solve, D